通过#使用`meson`

通过利用通过 numpy.distutils 使用meson中描述的技术获得的关键优势是，它可以轻松地输入到现有系统和更大的项目中。有一个相当Pythonic的语法，这使得它更舒适并且更适合用户扩展。mesonpython

笔记

至少需要介子0.46.0才能解析python包含目录。

斐波那契演练 (F77) #

在C使用像meson.我们将通过以下方式获得它：

python -m numpy.f2py fib1.f -m fib2

现在，考虑以下meson.build文件fib以及三种包装方式 - 入门scalar部分的示例：

project('f2py_examples', 'c',
  version : '0.1',
  license: 'BSD-3',
  meson_version: '>=0.64.0',
  default_options : ['warning_level=2'],
)

add_languages('fortran')

py_mod = import('python')
py = py_mod.find_installation(pure: false)
py_dep = py.dependency()

incdir_numpy = run_command(py,
  ['-c', 'import os; os.chdir(".."); import numpy; print(numpy.get_include())'],
  check : true
).stdout().strip()

incdir_f2py = run_command(py,
    ['-c', 'import os; os.chdir(".."); import numpy.f2py; print(numpy.f2py.get_include())'],
    check : true
).stdout().strip()

inc_np = include_directories(incdir_numpy, incdir_f2py)

py.extension_module('fib2',
  [
    'fib1.f',
    'fib2module.c',  # note: this assumes f2py was manually run before!
  ],
  incdir_f2py / 'fortranobject.c',
  include_directories: inc_np,
  dependencies : py_dep,
  install : true
)

此时构建将完成，但导入将失败：

meson setup builddir
meson compile -C builddir
cd builddir
python -c 'import fib2'
Traceback (most recent call last):
File "<string>", line 1, in <module>
ImportError: fib2.cpython-39-x86_64-linux-gnu.so: undefined symbol: FIB_
# Check this isn't a false positive
nm -A fib2.cpython-39-x86_64-linux-gnu.so | grep FIB_
fib2.cpython-39-x86_64-linux-gnu.so: U FIB_

回想一下，原始示例（如下所示）位于 SCREAMCASE 中：

C FILE: FIB1.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB1.F

使用标准方法，暴露给pythonisfib和 not 的子例程FIB。这意味着我们有几个选择。一种方法（如果可能）是将原始 Fortran 文件小写，例如：

tr "[:upper:]" "[:lower:]" < fib1.f > fib1.f
python -m numpy.f2py fib1.f -m fib2
meson --wipe builddir
meson compile -C builddir
cd builddir
python -c 'import fib2'

然而，这需要能够修改源代码，而这并不总是可能的。解决这个问题最简单的方法就是让f2py处理它：

python -m numpy.f2py fib1.f -m fib2 --lower
meson --wipe builddir
meson compile -C builddir
cd builddir
python -c 'import fib2'

自动生成包装器#

上述定义的工作流程中的一个主要痛点是手动跟踪输入。尽管出于F2PY 和 Build Systems中讨论的原因，需要付出更多努力来找出实际输出。

笔记

从 NumPy1.22.4开始，f2py将根据输入文件 Fortran 标准（F77 或更高版本）确定性地生成包装文件。 --skip-empty-wrappers可以传递来f2py恢复之前仅在输入需要时生成包装器的行为。

但是，我们可以直接扩展我们的工作流程，以考虑在设置构建系统时已知输出的文件。

project('f2py_examples', 'c',
  version : '0.1',
  license: 'BSD-3',
  meson_version: '>=0.64.0',
  default_options : ['warning_level=2'],
)

add_languages('fortran')

py_mod = import('python')
py = py_mod.find_installation(pure: false)
py_dep = py.dependency()

incdir_numpy = run_command(py,
  ['-c', 'import os; os.chdir(".."); import numpy; print(numpy.get_include())'],
  check : true
).stdout().strip()

incdir_f2py = run_command(py,
    ['-c', 'import os; os.chdir(".."); import numpy.f2py; print(numpy.f2py.get_include())'],
    check : true
).stdout().strip()

fibby_source = custom_target('fibbymodule.c',
  input : ['fib1.f'],  # .f so no F90 wrappers
  output : ['fibbymodule.c', 'fibby-f2pywrappers.f'],
  command : [py, '-m', 'numpy.f2py', '@INPUT@', '-m', 'fibby', '--lower']
)

inc_np = include_directories(incdir_numpy, incdir_f2py)

py.extension_module('fibby',
  ['fib1.f', fibby_source],
  incdir_f2py / 'fortranobject.c',
  include_directories: inc_np,
  dependencies : py_dep,
  install : true
)

这可以像以前一样编译和运行。

rm -rf builddir
meson setup builddir
meson compile -C builddir
cd builddir
python -c "import numpy as np; import fibby; a = np.zeros(9); fibby.fib(a); print (a)"
# [ 0.  1.  1.  2.  3.  5.  8. 13. 21.]

要点#

值得记住以下几点：

meson-fimplicit-none默认情况下会默认通过gfortran，这与标准np.distutils行为不同
在这种情况下不可能使用 SCREAMCASE，因此文件的内容.f或生成的包装器.c需要降低为常规字母；这可以通过以下--lower选项来促进F2PY

通过#使用meson

斐波那契演练 (F77) #

自动生成包装器#

要点#

通过#使用`meson`